Tip

Revision history using formula language

This formula allows you to keep a revision history in a single computed field. Unlike most such revision trackers, it does not rely on the QuerySave event. The formula tests if the current user's name is in the most recent entry in the field. If so, only the date is updated so you don't get multiple entries for the same person if there is no intervening editor. The results display like this:

Joe Smith 10/29/2001 12:40:08 PM
George Bush 10/29/2001 12:40:46 PM
Rob Pinion 10/29/2001 12:50:15 PM
George Bush 10/29/2001 12:50:41 PM

thisUser:=@Name([CN];@UserName);

REM "To use this function change the field name below from displayUpdater to your field name";
REM "The field should be Text, computed, allow multiple values, display separate entries with New Line";
thisfield:=displayUpdater;

REM "Assign all current lines in this field to a temporary variable";
existingLines:=thisfield;

REM "Each new line will have the user's name and the current date-time";
newLine:=thisUser+" "+@Text(@Now);

REM "Now compare to see if the current user is the most recent editor";
REM "Get the last entry since it contains the most recent editor";

REM "First get a count of the number of lines --- elements --- already there";
numLines:=@Elements(existingLines);

REM "If there's only one line assign it to lastEntry var, otherwise assign the last entry to lastEntry var";
lastEntry:=@If(numLines=1;existingLines;@Subset(existingLines;-1));

REM "Test whether the last line contains the name of the current user";
REM "Later we want to replace that line rather than adding a new line every time he saves the doc";
isSameUser:=@Contains(lastEntry;thisUser);

REM "Now get all lines but the last line";
allButLast:=@If(numLines=1;"";@Subset(existingLines;numLines-1));

REM "If the doc is being saved, then if this is same user return all but the last line followed by the new line";

REM "If this is not the same user, return everything preexisting plus a new line";

REM "If the doc is not being saved just show the contents of the field";

@If(@IsDocBeingSaved;@If(isSameUser;allButLast:newLine;thisfield:newLine);thisfield)

This was first published in November 2001

There are Comments. Add yours.

 
TIP: Want to include a code block in your comment? Use <pre> or <code> tags around the desired text. Ex: <code>insert code</code>

REGISTER or login:

Forgot Password?
By submitting you agree to receive email from TechTarget and its partners. If you reside outside of the United States, you consent to having your personal data transferred to and processed in the United States. Privacy
Sort by: OldestNewest

Forgot Password?

No problem! Submit your e-mail address below. We'll send you an email containing your password.

Your password has been sent to:

Disclaimer: Our Tips Exchange is a forum for you to share technical advice and expertise with your peers and to learn from other enterprise IT professionals. TechTarget provides the infrastructure to facilitate this sharing of information. However, we cannot guarantee the accuracy or validity of the material submitted. You agree that your use of the Ask The Expert services and your reliance on any questions, answers, information or other materials received through this Web site is at your own risk.